请教一个关于死单元的问题

河砂

为了模拟混凝土的浇注过程，我用了死单元来分析混凝土随时间的温度变化。但分析后死单元上仍有温度变化。另外如果把两块体中一块定义为死单元，另一块加自生热荷载，则会出现如下错误“Solution not converged at time 1(load step 1 substep 1) Run terminated”请问这种情况是怎么回事？毕业在即，急需解答，在此先谢过！
我用的命令流如下：
/filnam,shiyan
/units,si
/prep7
et,1,solid70
mp,ex,1,3.2e10
mp,kxx,1,1263.774e-2
mp,dens,1,2450e-6
mp,c,1,0.9672
mp,nuxy,1,0.167
mp,ex,2,2.5e10
mp,kxx,2,7.3
mp,dens,2,15000e-6
mp,c,2,1.84
mp,nuxy,2,0.35
*dim,air,table,30,1
*SET,air(1,0),1,2,3,4,5,6,7,8,9,10
*SET,air(11,0),11,12,13,14,15,16,17,18,19,20
*SET,air(21,0),21,22,23,24,25,26,27,28,29,30
*SET,air(1,1),-2.7,0.1,2.1,3.6,5.4,1.7,1.6,4.4,5.7,5.4
*SET,air(11,1),5.8,6.7,7.9,11.3,15,17,16.6,18.1,19.9,22.6
*SET,air(21,1),23.7,25.3,26.5,28.2,31.2,29.1,27.4,26.5,24.6,22.1
*dim,sita,table,9
sita(1,0)=1,3,7,10，13,16,19,23,26
sita(1,1)=7.8,1.9,0.486,0.22,0.13,0.064,0.03,0.0176,0.0114
block,0,4000,-2000,0,-3000,3000
block,0,1500,0,6000,-3000,3000
vglue,all
numcmp,volu
accat,13,17
mshkey,1
mshape,0
vatt,1,1,1
vmesh,1
vatt,2,1,1
vmesh,2
finish
/solu
antype,trans
outres,all,all
trnopt,full
timint,on
ic,all,temp,-2.7
nropt,full
esel,s,mat,,1
nsle,s,
ekill,all
allsel
*do,tt,1,30,1
time,tt
！加体载荷出现不收敛       !也可加面载，计算后死单元上仍有温度变化
esel,s,mat,,2              !asel,s,area,,5,6,1
nsle,s                     
bfe,all,hgen,,%sita%       !sfa,all,,conv,80,%air%
allsel
solve
*enddo

crystallzss

这边有一个关于“用单元死活模拟浇铸过程中的温度分布”的例子，应该对你很有用，如果发现是哪里出问题了，记得上来分享一下哦：）
要想对浇铸过程的温度场进行分析,必须熟悉下面两个方面的内容：1.瞬态温度场的分析,2.单元死活的应用。
瞬态温度场分析：在进行瞬态温度分析时,我们常遇到的一个问题是温度结果明显不合理，:计算得到的温度高于给定的最高温度或低于给定的最低温度。造成这种结果的原因有两个：1、单元不合理，网格太大。2、时间积分方法不恰当。针对上述两个原因，我们采取的措施是：1、细划网格。2、选择向后积分法（THETA=1）。
单元死活：应用单元死活进行分析时,需要用到多个载荷步。在不同的载荷步之间单元的死活状态不同,ANSYS的通用动画生成工具生成的动画无法表现单元状态随时间的变化,因此必须使用ANSYS的DISPLAY Utility来生成能够表现单元死活状态的动画。
下面是一个简单的模拟浇铸过程的例子，环境温度为70，浇铸温度为600，计算结果应是：最低温度不低于70，最高温度不高于600。如果我们划分的网格不适当，则会出现最低温度低于70或最高温度高于600的情况，因此必须细划网格并选择THETA=1。计算完成后使用ANSYS的DISPLAY Utility来生成动画文件。
fini
/cle
/prep7
et,1,55
et,2,55
KXX , 1,1.99/3600
DENS,1,0.00073
C ,1,0.100
KXX,2,7.38E-6
DENS,2,9.35E-5
c,2,1
k,1,-.5,-.5
k,4,6,-.5
k,12
k,13,5.5
k,21,-.5,6
k,22,,6
k,23,5.5,6
k,24,6,6
a,12,13,23,22
a,1,12,22,21
a,1,4,13,12
a,4,24,23,13
lsel,s,,,5,6
lsel,a,,,9,11,2
lesize,all,,,8
lsel,all
lesize,all,,,20
asel,s,,,1
aatt,2,2,2
asel,all
amesh,all
fini
/solu
antype,tran
!solc,on
timint,off
lsel,s,,,7,8
lsel,a,,,10
nsll,s
sf,all,conv,100,70
alls
esel,s,type,,2
nropt,full
ekill,all
alls
tunif,100
time,1
outres,all,all
solve
dtop=0
tim=1
delt=.05
timint,on
tintp,,,,1
*do,ii,1,20
ddele,all,temp
esel,s,type,,2
nsle,s
tim=tim+delt
time,tim
dtop=dtop+.3
nsel,r,loc,y,0,dtop
esln,s,1
ealive,all
nsel,r,loc,y,dtop
esln,s
nsle,s,1
d,all,temp,600
eplot                  !画出单元，使看得清楚
esel,s,live
eplot
nall
eall
solve
*enddo
fini
/show,tmpplt,f33
/post1
dtop=0
*do,ii,2,21
set,ii
dtop=dtop+.3
nsel,r,loc,y,0,dtop
esln,s,1
esel,a,type,,1
nall
plns,temp
*enddo

河砂

首先感谢这位大哥给我这个例题，不过我还没整出来。不知怎么搞的，作结构分析好好的，但应用到温度上就不正确了，小弟已经一个多星期都在搞这个东西了，请那位兄弟知道了请赶快点拨一下小弟，小弟感激不尽！

crystallzss

这边还有一个关于混凝土浇注的问题
供参考
!大伙看看，有何问题，如何改进？
!100*80*10基岩上浇筑混凝土50*40*10，每三天浇筑1米高（第一天浇完，剩下两天窝工），
!共用一个月时间,分为十层（layer)浇筑，模型、条件均为假设
!建模
/filename,test
/PREP7
BLOCK,,50,,10,,40,
BLOCK,-25,75,-10,0,-20,60
ET,1,70
LSEL,S,,,9,12,1
LESIZE,ALL,,,10
LSEL,S,,,21,24,1
LESIZE,ALL,,,20
LSEL,S,,,2,4,2
LSEL,A,,,5,7,2
LESIZE,ALL,,,10
LSEL,S,,,14,16,2
LSEL,A,,,17,19,2
LESIZE,ALL,,,20
LSEL,S,,,1,3,2
LSEL,A,,,6,8,2
LESIZE,ALL,,,10
LSEL,S,,,13,15,2
LSEL,A,,,18,20,2
LESIZE,ALL,,,5
allsel
MP,DENS,1,2400.0 !混凝土材料
MP,KXX ,1,300.89
MP,C,1,0.94500
MAT,1
VMESH,1
MP,DENS,2,2600.0 !基岩材料
MP,KXX ,2,300.89
MP,C,2,0.94500
MAT,2
VMESH,2
nummrg,all
!热分析
/SOLU
NROPT,FULL !Specifies the Newton-Raphson options in full transient analysis
ESEL,S,MAT,,2 !MAT2 IS 基岩
NSLE,S
IC,all,TEMP,16.4, !加基岩初温
ASEL,S,,,7,9,1
ASEL,A,,,11,12,1
NSLA,S,1
SF,all,HFLUX,0 !加基岩绝热边界条件
NSEL,S,LOC,Y,-0.1,0.1
ASEL,S,,,3
NSLA,U,1
SF,ALL,CONV,2016,20 !加基岩第三边界条件（和空气接触面）
!加初始条件
ALLSEL,ALL
ESEL,U,MAT,,2
NSLE,S
EKILL,ALL !KILL 混凝土
IC,all,TEMP,35, !混凝土浇筑时温度为35度
ANTYPE,TRANSIENT,new !分析类型
!日子的流逝
*DO,LAYER,1,10,1
  !激活第N层单元
  ALLSEL,ALL
  NSEL,S,LOC,Y,(LAYER-1),LAYER !第一层从Y=0~1米，第二层从Y=1~2米,...
  ESLN,S ,1
  EALIVE,ALL
  *DO,DAY,LAYER*3-2,LAYER*3,1 !每三天浇筑一层
    ALLSEL,ALL
    ASEL,S,,,1,2,1
    ASEL,A,,,5,6,1
    NSLA,S,1
    NSEL,R,LOC,Y,0,LAYER
    NSEL,A,LOC,Y,LAYER-0.1,LAYER+0.1
    SF,ALL,CONV,2016,20 !加混凝土第三类对流边界条件
    *DO,LOOP,1,LAYER,1
      ALLSEL,ALL
      NSEL,R,LOC,Y,LOOP-1,LOOP
      ESLN,S,1
      TDAY=DAY-(LOOP-1)*3 !已经完工的天数
      HE00=47880*(TDAY/(0.862+TDAY)-(TDAY-1)/(0.862+TDAY-1))
      BFE,ALL,HGEN, ,HE00 !加水化热
    *ENDDO
    !计算设置
    ALLSE
    TRNOPT,FULL
    LUMPM,0
    TIME,DAY
    AUTOTS,0
    DELTIM,1, , ,1
    KBC,0
    TSRES,ERASE
    OUTRES,ALL,ALL,
    SOLVE
  *ENDDO
  ESEL,S,MAT,,1
  NSLE,S,
  SFEDELE,ALL,ALL,CONV !删对流边界条件
  SFDELE,ALL,CONV
*ENDDO
FINISH
   
!结构分析
/PREP7
ET,1,SOLID65 !变热单元为结构单元
*DIM,EXX,ARRAY,30 !考虑变化的EX
EXX(1)=0.325E10,0.57778E10,0.78E10,0.94545E10,0.10833E11,0.12E11,0.13E11,0.13867E11,0.14625E11,0.15294E11, 0.15889E11, 0.1642E11 ,0.169E11, 0.17333E11, 0.17727E11, 0.18087E11,0.18417E11,0.1872E11
EXX(19)=0.190E11, 0.19259E11, 0.195E11, 0.19724E11, 0.19933E11, 0.20129E11,0.20312E11, 0.20485E11, 0.20647E11, 0.208E11, 0.20944E11, 0.21081E11
*DO,I,1,30,1 !定义材料，混凝土浇筑完每过一天变一种材料
    MP,DENS,I,2400
    MP,EX,I,EXX(I)
    MP,PRXY,I,0.167
    MP,ALPX,I,0.9E-5
    MP,REFT,I,15
*ENDDO
MP,DENS,31,2600 !定义基岩材料
MP,EX,31,0.20800E+11
MP,PRXY,31,0.167
MP,ALPX,31,0.9E-5
ESEL,S,MAT,,,2
MPCHG,31,ALL, !!变热材料为结构材料
ALLSEL
/SOLU
NROPT,FULL !Specifies the Newton-Raphson options in a full transient analysis
NLGEOM,ON
NSLA,S,,,7,9,1
NSLA,A,,,11,12,1
D,all,ALL !加基岩约束
!KILL THE CONCRETE ELEMENT
ESEL,U,MAT,,1
NSLE,S
EKILL,ALL !KILL 混凝土
*DO,DAY,1,30,1 !随时间改变，变换材料
  *DO,LAYER,1,10
      *IF,DAY,GT,LAYER*3-3,THEN
          NSEL,S,LOC,Y,LAYER-1,LAYER
          ESLN,S,1
          EALIVE,ALL !ACTIVE NEXT LAYER
          MPCHG,DAY-(LAYER-1)*3,ALL, !CHANG MAT
          ALLSEL,ALL
      *ENDIF
  *ENDDO
  ALLSEL,ALL
  ACEL,0,0,-9.8, !GRAVITY LOAD
  LDREAD,TEMP,,,DAY, ,';TEST';,';rth';,'; '; !TEMP LOAD Reads results from the results file and applies them as loads.
  CNVTOL,F, ,0.2,2,200, !Sets convergence values for nonlinear analyses.
  TIME,DAY
  AUTOTS,0
  DELTIM,1, , ,1
  KBC,0
  TSRES,ERASE !Defines an array of keytimes at which the time-stepping strategy changes
  OUTRES,ALL,ALL,
  SOLVE
*ENDDO
!1、定义重力集散地是应为正值：ACEL,0,0,9.8
!2、砼单元边长（1*4*5）相差5倍，对计算精度的影响会不会较大？
!3、热单元SOLID70对应的结构单元为SOLID45，改为SOLID65是否合适？
!4、原分析得到的结果与实际情况比较如何？
!5、如何体现气温的变化？